libwacom: versionbump 2.1

dev-libs/libwacom/Manifest

@@ -0,0 +1,2 @@
+DIST libwacom-1.11.tar.bz2 519285 BLAKE2B fb26190d752316b5d25659d2ae76681bfff1803463360aa138eab91ed7d7ef2d04dfb6bdd4f8c2effc45a495ef3afc312a817d4fd41cd8167172cafd9f5cee9f SHA512 24e8183502dd2b928d53b3d26d8479210e855c94c225649d63ac33062a30615654ff0ab8666a25503fb3253125539cd845ca467fb228a01c608dc3adbbec73b5
+DIST libwacom-2.1.0.tar.xz 106080 BLAKE2B ae57fadeec357a186a6cfbb493f47f1b52956e62a643bee1d466102aaf1a588cc57fc5e20117185077bf8fb550cc42e2ff97fd6307cbd2f9befb5b5535ca7946 SHA512 9da7a6467ee9d853fca8d7b58528cb7c7a2f28f4074dba76e1d76cd6c134d800e1f8ad672b997af96f8712fc407d7d64cbdd1bcb4d8ae67965217786bbabca4a

dev-libs/libwacom/libwacom-2.1.0.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit meson python-any-r1 toolchain-funcs udev
+
+DESCRIPTION="Library for identifying Wacom tablets and their model-specific features"
+HOMEPAGE="https://github.com/linuxwacom/libwacom"
+SRC_URI="https://github.com/linuxwacom/${PN}/releases/download/${P}/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm ~arm64 ~ia64 ppc ppc64 sparc x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/libgudev:=
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	test? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep '
+			dev-python/python-libevdev[${PYTHON_USEDEP}]
+			dev-python/pyudev[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+python_check_deps() {
+	has_version -b "dev-python/python-libevdev[${PYTHON_USEDEP}]" &&
+	has_version -b "dev-python/pyudev[${PYTHON_USEDEP}]" &&
+	has_version -b "dev-python/pytest[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	tc-ld-disable-gold # bug https://github.com/linuxwacom/libwacom/issues/170
+
+	if use test; then
+		python-any-r1_pkg_setup
+	fi
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature doc documentation)
+		$(meson_feature test tests)
+		-Dudev-dir=$(get_udevdir)
+	)
+	meson_src_configure
+}

dev-libs/libwacom/metadata.xml

@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>freedesktop-bugs@gentoo.org</email>
+	</maintainer>
+	<upstream>
+		<remote-id type="sourceforge">linuxwacom</remote-id>
+	</upstream>
+</pkgmetadata>